Is it possible to configure [DIS_UAC] equivalent with 1082?

[Ligonet]

Wondering, that I cannot find any discussion about this. New SC added the [DIS_UAC] section to helpfile.txt. This is a miraculous good thing and eases remote-support a lot.

As newer UVNC is able to work like Single Click with appropriate startup options, I tried to achieve dis_uac equivalent with the standard server, but until now it looks to me, that this is not available. Is it?

[supercoe]

Correct the option doesn't exist in the standard server.

Here are a couple batch files that will do what you want. Remember to right click and run them as administrator.

disableuac.cmd

Code: Select all

reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System /v PromptOnSecureDesktop_VNC
IF ERRORLEVEL 0 IF NOT ERRORLEVEL 1 goto made_copy_posd

:: delims is a TAB followed by a space
FOR /F "tokens=2* delims=	 " %%A IN ('REG QUERY "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v PromptOnSecureDesktop') DO SET OrigSetting=%%B
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v PromptOnSecureDesktop_VNC /t REG_DWORD /d %OrigSetting%
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v PromptOnSecureDesktop /t REG_DWORD /d 0 /f
:made_copy_posd

reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System /v ConsentPromptBehaviorAdmin_VNC
IF ERRORLEVEL 0 IF NOT ERRORLEVEL 1 goto made_copy_cpba

:: delims is a TAB followed by a space
FOR /F "tokens=2* delims=	 " %%A IN ('REG QUERY "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v ConsentPromptBehaviorAdmin') DO SET OrigSetting=%%B
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v ConsentPromptBehaviorAdmin_VNC /t REG_DWORD /d %OrigSetting%
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v ConsentPromptBehaviorAdmin /t REG_DWORD /d 0 /f
:made_copy_cpba
EXIT

enableuac.cmd

Code: Select all

reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System /v PromptOnSecureDesktop_VNC
IF ERRORLEVEL 0 IF NOT ERRORLEVEL 1 goto replace_copy_posd
goto replace_cpba

:replace_copy_posd
FOR /F "tokens=2* delims=	 " %%A IN ('REG QUERY "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v PromptOnSecureDesktop_VNC') DO SET OrigSetting=%%B
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v PromptOnSecureDesktop /t REG_DWORD /d %OrigSetting% /f
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v PromptOnSecureDesktop_VNC /f

:replace_cpba
reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System /v ConsentPromptBehaviorAdmin_VNC
IF ERRORLEVEL 0 IF NOT ERRORLEVEL 1 goto replace_copy_cpba
goto end

:replace_copy_cpba
FOR /F "tokens=2* delims=	 " %%A IN ('REG QUERY "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v ConsentPromptBehaviorAdmin_VNC') DO SET OrigSetting=%%B
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v ConsentPromptBehaviorAdmin /t REG_DWORD /d %OrigSetting% /f
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v ConsentPromptBehaviorAdmin_VNC /f

:end
EXIT

[Ligonet]

Great, thanks a lot

Hopefully the product will support it as an option in the future